Cacher tout ou une partie des icônes du bureau de Windows

Vidéo illustrative via YouTube

Cacher toutes les icônes du bureau de Windows

Pour cacher toutes les icônes du bureau de Windows, procédez comme suit :

• Faites un clic droit sur une zone vide de votre bureau.
• Sélectionnez l'option Affichage sur le menu contextuel.
• Décochez l'option Afficher les icônes du bureau.

Cette opération masque toutes les icônes du bureau ; vous pouvez les rendre visibles à nouveau en cochant l'option Afficher les icônes du bureau.

Cacher une partie des icônes du bureau de Windows

Pour cacher une partie des icônes du bureau de Windows je vous propsoe un script VBScript. Il permet de manipuler les attributs d'affichage des fichiers et des dossiers situés sur le bureau et n'interfère qu'avec les fichiers et les dossiers dont le nom commence par un caratère ou une chaine de caratères qu vous définissez.

Dans mon exemple j'ai utilisé le caractère underscore _.

Le script récupère ainsi tous les fichiers et dossiers présents sur le bureau puis il parcourt chaque fichier et dossier. Si le nom de l'élément commence par le caractère _, il modifie les attributs d'affichage de l'élément.

Mon script permet donc de cacher ou de rendre visible une partie des fichiers et des dossiers du bureau de Windows.

Voci le code source :

Set objShell = CreateObject("WScript.Shell")
Set objFSO = CreateObject("Scripting.FileSystemObject")

' Définir les constantes attribut (2 = Attribut caché (Hidden) et 4 = Attribut système (System))
Const ATTR_CACHER = 2
Const ATTR_SYSTEME = 4

' Définir le caractère de début des noms des fichiers et dossiers (à adapter comme bon vous semble)
Const CARACTERE_DEBUT = "_"

' Obtenir le chemin du bureau pour l'utilisateur actuel
cheminBureau = objShell.SpecialFolders("Desktop")

' Fonction pour inverser les attributs "Hidden" et "System"
Sub InverserAttributsCachesEtSysteme(element)
If (element.Attributes And ATTR_CACHER) = ATTR_CACHER Then
' Enlever les attributs "Hidden" et "System"
element.Attributes = element.Attributes And Not ATTR_CACHER
element.Attributes = element.Attributes And Not ATTR_SYSTEME
Else
' Ajouter les attributs "Hidden" et "System"
element.Attributes = element.Attributes Or ATTR_CACHER
element.Attributes = element.Attributes Or ATTR_SYSTEME
End If
End Sub

' Fonction pour rafraîchir le bureau
Sub RafraichirBureau()
objShell.AppActivate "Program Manager"
objShell.SendKeys "{F5}"
End Sub

' Récupérer tous les fichiers et dossiers du bureau
Set dossier = objFSO.GetFolder(cheminBureau)

' Traiter tous les éléments du bureau (fichiers et dossiers)
For Each element In dossier.Files
If Left(element.Name, 1) = CARACTERE_DEBUT Then
InverserAttributsCachesEtSysteme element
End If
Next

For Each element In dossier.SubFolders
If Left(element.Name, 1) = CARACTERE_DEBUT Then
InverserAttributsCachesEtSysteme element
End If
Next

' Rafraîchir le bureau après traitement
RafraichirBureau()